データー出力側のテスト。

こんな感じで、Arduino の Software シリアルを使って、RX(D4)はJunction-BOXからの入力、TX(D6)はPC側への出力に。

ただ、TXをそのままUSB-SERIALにぶち込むと、ピンの電圧でUSB-SERIALに電流流れちゃうので、実際動いている時だけTX出力するため、D5で制御のフォトリレー(TLP222)経由にしてみた。

↓んでもって、そのテスト。

USB-SERIALは、PL2303チップなやつでテスト！

問題なし！

/*
 *  CAMP JUNCTION BOX Reciver
 *  Version 0.2
 *  2017-06-20 10:59
 */
#define DEBUG 1

#include <SoftwareSerial.h>        // Software Serial Library
#include <FlexiTimer2.h>           // Timer Library

#define RX             4
#define TX             6
#define	CTRL           5

SoftwareSerial mySerial(RX,TX);

volatile double PRESS1=-999.0;
volatile double TEMP_L=-99.0;

void update_data(unsigned int,unsigned int,unsigned int,unsigned int);

void output_data(){ // データ出力
  #if DEBUG
  Serial.print("TEMPL:");
  Serial.print(TEMP_L);
  Serial.print(",PRESS1:");
  Serial.print(PRESS1);
  Serial.print("\n");
  #endif
  mySerial.print(TEMP_L);
  mySerial.print(",");
  mySerial.print(PRESS1);
  mySerial.print("\n");
}

void setup() {
  // pin
  pinMode(CTRL,OUTPUT);
  digitalWrite(CTRL,HIGH);   // Photo-Relay ON
 
  // Serial
  mySerial.begin(9600);
  #if DEBUG
  Serial.begin(115200);
  #endif

  // Timer
  FlexiTimer2::set(500, 1.0/1000, output_data);
  FlexiTimer2::start();
}

void loop() {
  unsigned char ch;
  unsigned int buf[10];
  int pos=0;
  byte stat=0;

  buf[0]=0;buf[1]=0;buf[2]=0;buf[3]=0;
  
  while(1){
    while(mySerial.available()){
      ch=mySerial.read();
      if(ch==0x80 || ch==0x81 || ch==0x82 || ch==0x83){
        pos=0;
        if(ch==0x81 || ch==0x82)stat=1;
        else stat=0;
      }
      if(pos<4){
        buf[pos]=ch;
        pos++;
      }
      if(stat==1 && pos==4){
        update_data(buf[0],buf[1],buf[2],buf[3]);
      }
    }
    delay(5);
  }
}

// データ更新(GLOBAL変数のTEMP_L,PRESS1)
void update_data(unsigned int d1,unsigned int d2,unsigned int d3,unsigned int d4){
  if(d1==0x81){                                   // TEMP-L
    double temp_l;
    int temp_l0;

    temp_l0=d3*128+d4;
    if(d2==0x50){
      temp_l=(double)temp_l0 / 10.0;
    } else {
      temp_l=0.0-( (double)temp_l0 / 10.0);
    }
    TEMP_L=temp_l;
  } else if(d1==0x82 || d1==0x83){                // PRESS
    double press1;
    int press1i;

    press1i=d3*128+d4;
    
    if(d2==0x50){                                 // 正圧
      press1=(double)press1i*0.98067;             // kgf/cm2 -> kPa
    } else {                                      // 負圧
      press1=0.0-(double)press1i*101.325/760.0;   // mmHg -> kPa
    }
    PRESS1=press1;
  }
}

続く〜